Win10/11 禁止自己电脑更新

也是太过于无聊了,然后我就想了一个方法让自己电脑不更新,因为有时候更新电脑一些软件都适配不了,而且还偷偷摸摸给你更新,抽根烟的工作就自动更新了,然后就想了一个方法

正如你看到的那样,目前更新就是 2099 年更新,接下来就来给大家说说这个该怎么做

教程

首先,你得在电脑桌面上面创建一个文本,右键新建文本文件,把下面代码复制过去

@echo off
MODE con: COLS=90 LINES=28
title Loading
rem 自动提权以管理员方式运行
%1 Start "" Mshta Vbscript:createobject("Shell.Application").Shellexecute("""%~0""","::",,"Runas",1)(Window.close)&Exit

@echo off
MODE con: COLS=90 LINES=30
setlocal

:Start
title 禁止/恢复 Windows 10/11更新工具
cls
echo.
echo.
echo.
echo.
echo.=========================    禁止/恢复 Windows 10/11更新工具    ==========================
echo.
echo.
echo.  禁用 Windows 更新服务会影响自带驱动程序更新、Microsoft Store 及Xbox 游戏
echo.  的正常运行。
echo.
echo.  该工具利用 Windows 自带的暂停更新选项,直接暂停更新1000周,以实现“屏蔽更
echo.  新”功能,但不影响其他功能正常使用,随时可使用该工具恢复正常更新。
echo.
echo.
echo.
echo.              Blog:te.ink
echo.
echo.   请选择你的操作:
echo.
echo.    [1] 暂停至2099年
echo.
echo.    [2] 恢复正常更新
echo.
echo.    [3] 退出工具
echo.
echo.
echo.
set /p choice=请输入选项号码:

IF "%choice%"=="1" (
  goto Disable
) ELSE IF "%choice%"=="2" (
  goto Enable
) ELSE IF "%choice%"=="3" (
  exit
) ELSE (
  echo. 
  echo.   无效的选项,请重新输入。
  echo. 
  goto Start
)


:Disable
title 暂停Windows 10/11 更新1000周
echo.
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings" /v "FlightSettingsMaxPauseDays" /t REG_DWORD /d 27740 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings" /v "PauseFeatureUpdatesStartTime" /t REG_SZ /d "2023-07-07T10:00:52Z" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings" /v "PauseFeatureUpdatesEndTime" /t REG_SZ /d "2099-01-01T09:59:52Z" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings" /v "PauseQualityUpdatesStartTime" /t REG_SZ /d "2023-07-07T10:00:52Z" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings" /v "PauseQualityUpdatesEndTime" /t REG_SZ /d "2099-01-01T09:59:52Z" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings" /v "PauseUpdatesStartTime" /t REG_SZ /d "2023-07-07T09:59:52Z" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings" /v "PauseUpdatesExpiryTime" /t REG_SZ /d "2099-01-01T09:59:52Z" /f
echo.
goto end


:Enable
title 恢复Windows 10/11 正常更新
echo.
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings" /f
echo.
goto end

:End
echo.
echo.  操作完成,按任意键返回!
pause>nul
start "" "https://te.ink/archives/163.html"
goto Start

然后我们点击左上角的 文件另存为

然后我们把文件txt后缀改成bat,然后编码我们还要改成 ANSI

再然后我们就保存它就行了,在桌面上双击这个bat文件就会出现下面的命令框,然后再输入一个1然后回车就ok了

目前适配了Windows10/11,稳定可靠,反正就是挺好用的就对了

消息盒子
# 您需要首次评论以获取消息 #
# 您需要首次评论以获取消息 #

只显示最新10条未读和已读信息